home *** CD-ROM | disk | FTP | other *** search
/ START Magazine / START VOL 4 NO 7.st / X10CTRL.ARC / DARKROOM.GFA (.txt) < prev    next >
Encoding:
GFA-BASIC Atari  |  1989-11-16  |  35.6 KB  |  1,646 lines
  1. '
  2. ' DARKROOM 3/01/89   Howard MacOdrum
  3. ' Copyright 1990 by Antic Publishing, Inc.
  4. '
  5. path$=DIR$(0)+"\"
  6. RESERVE FRE(0)-16000
  7. rsconf|=15
  8. baud|=8
  9. flow|=0
  10. ucr|=&X10001000
  11. rsr%=-1
  12. tsr%=-1
  13. scr%=-1
  14. DIM x10cmnd|(28)
  15. ARRAYFILL x10cmnd|(),&HFF
  16. DIM unit_desc$(16,15)
  17. DIM hsuntab|(16,16)     ! House unit table will contain 0 if unit off or 1-16 if on
  18. REM                       or during file analysis, step unit was turned on
  19. '
  20. anlmsg1$=" file errors found,|select video or|ready printer."
  21. anlmsg3$="Error code 1 = Unit(s) turned off but not on."
  22. anlmsg4$="Error code 2 = Unit(s) turned on but were on in ""Prev step""."
  23. anlmsg5$="Error code 3 = Unit left in ""ON"" status,"
  24. DIM onunit$(16)
  25. DIM dayhex|(6)
  26. DIM daystr$(6)
  27. DIM ansfil$(50,5)   ! 50 errors- step,reason,prev on,house,units
  28. DIM x10reply|(1050)
  29. DIM househex|(16)
  30. DIM funct|(16)
  31. DIM upfld$(7)
  32. maxitems|=128
  33. noflds|=6            !  # fields 7 and they are: time,function,house,units,security,day  & Desc
  34. DIM stpfil$(noflds|,maxitems|+1)
  35. FOR cy|=0 TO maxitems|+1
  36.   FOR cx|=0 TO noflds%
  37.     READ stpfil$(cx|,cy|)
  38.   NEXT cx|
  39.   RESTORE inaster
  40. NEXT cy|
  41. inaster:
  42. DATA ***,***,***,***,***,***,***
  43. RESTORE hexcodes
  44. FOR cx|=1 TO 16
  45.   READ househex|(cx|)
  46.   READ funct|(cx|)
  47. NEXT cx|
  48. funct|(0)=3
  49. hexcodes:
  50. DATA &h60,2,&He0,&H15,&h20,&h25,&hA0,&h35,&H10,&h45,&H90,&h55,&h50,&H65,&hd0,&h75
  51. DATA &H70,&h85,&Hf0,&h95,&h30,&Ha5,&hb0,&Hb5,&h00,&Hc5,&h80,&Hd5,&h40,&he5,&hc0,&hf5
  52. RESTORE daycode
  53. FOR cx|=0 TO 6
  54.   READ dayhex|(cx|)
  55.   READ daystr$(cx|)
  56. NEXT cx|
  57. daycode:
  58. DATA 64,Sunday,1,Monday,2,Tuesday,4,Wednesday,8,Thursday,16,Friday,32,Saturday
  59. DIM message%(3)
  60. mes_adr%=V:message%(0)
  61. ABSOLUTE evt&,mes_adr%
  62. ABSOLUTE tit&,mes_adr%+6
  63. ABSOLUTE obj&,mes_adr%+8
  64. ok%=RSRC_LOAD(path$+"DARKROOM.RSC")
  65. IF ok%=0
  66.   ALERT 3,"Error loading DARKROOM.RSC",1," OK ",z|
  67.   RESERVE FRE(0)+16000
  68.   EDIT
  69. ENDIF
  70. '
  71. ' Start of RESOURCE FILE definitions, see note in Blurb.
  72. '
  73. ~RSRC_GADDR(0,0,menu_adr%)
  74. ~RSRC_GADDR(0,1,stp_scrl_adr%)
  75. scrl_f_det_line|=2
  76. scrl_l_det_line|=17
  77. scrl_up|=19
  78. scrl_down|=21
  79. scrl_sort|=22
  80. scrl_return|=23
  81. ~RSRC_GADDR(0,2,stp_updt_adr%) ! update step detail
  82. up_step|=1
  83. up_old|=4
  84. up_new|=5
  85. up_time|=6
  86. up_desc|=7
  87. up_off_func|=10
  88. up_on_func|=11
  89. up_l_func|=26
  90. up_f_house|=28
  91. up_l_house|=43
  92. up_f_unit|=46
  93. up_l_unit|=61
  94. up_sun_day|=64
  95. up_sat_day|=70
  96. up_norm|=73
  97. up_secr|=74
  98. up_insert|=75
  99. up_delete|=76
  100. up_d_units|=77
  101. up_adjust|=78
  102. ' up_return|=79
  103. ~RSRC_GADDR(0,3,adj_tim_adr%)   ! adjust  steps time
  104. adj_value|=3
  105. adj_plus|=5
  106. adj_minus|=6
  107. ' adj_exit|=7
  108. ~RSRC_GADDR(0,4,x10_base_adr%)      ! Find and change base code
  109. x10_base_a|=4
  110. x10_base_p|=19
  111. ' x10_base_return|=20
  112. ~RSRC_GADDR(0,5,x10_clock_adr%)     ! find and change x10 clock
  113. x10_clk_tim|=3
  114. x10_clk_sun|=8
  115. ~RSRC_GADDR(0,6,x10_direct_adr%)    ! Direct commands
  116. x10_dir_hous_a|=3
  117. x10_dir_unit_1|=21
  118. x10_dir_unit_9|=29
  119. x10_dir_func_off|=40
  120. x10_dir_func_on|=41
  121. x10_dir_display_unit|=57
  122. x10_dir_execute|=58
  123. ' x10_dir_retrn|=59
  124. ~RSRC_GADDR(0,7,unit_desc_adr%)     ! unit descriptions
  125. ud_house|=2
  126. ud_house_desc|=3
  127. ud_unit_desc1|=5
  128. ud_unit_desc16|=20
  129. ud_house_up|=23
  130. ud_house_prev|=24
  131. '
  132. '
  133. resolution|=XBIOS(4)
  134. IF resolution|<>2
  135.   ALERT 3,"Sorry, DARKROOM runs in|high resolution",1," OK ",blob#
  136.   GOSUB quit
  137. ELSE
  138.   vlim%=399
  139.   ry|=2
  140. ENDIF
  141. PBOX 0,0,639,vlim%
  142. PRINT AT(30,15);"  Welcome to DARKROOM  "
  143. ~MENU_BAR(menu_adr%,1)
  144. DO
  145.   ~EVNT_MULTI(&X110000,0,0,0,0,0,0,0,0,0,0,0,0,0,mes_adr%,100,d%,d%,d%,d%,d%,d%)
  146.   IF evt&=10
  147.     one$=TRIM$(CHAR{OB_SPEC(menu_adr%,obj&)})
  148.     TOPW #2
  149.     FULLW #2
  150.     CLEARW 2
  151.     TITLEW #2,"DARKROOM      Sub function  - "+one$
  152.     IF one$="About DARKROOM"
  153.       GOSUB blurb
  154.     ELSE IF one$="Load"
  155.       GOSUB load_step_file
  156.     ELSE IF one$="Save"
  157.       GOSUB store_step_file
  158.     ELSE IF one$="Update steps"
  159.       GOSUB stp_scroll_det
  160.     ELSE IF one$="Print steps"
  161.       GOSUB print_steps
  162.     ELSE IF one$="Update units"
  163.       GOSUB update_unit_desc
  164.     ELSE IF one$="Print units"
  165.       GOSUB print_units
  166.     ELSE IF one$="Analysis"
  167.       GOSUB file_analysis
  168.     ELSE IF one$="Quit"
  169.       GOSUB quit
  170.     ELSE IF one$="Run from file"
  171.       GOSUB run_x10
  172.     ELSE IF one$="File to X10"
  173.       GOSUB file_to_x10
  174.     ELSE IF one$="X10 to Printer"
  175.       GOSUB x10_print
  176.     ELSE IF one$="Base Code"
  177.       GOSUB base_code
  178.     ELSE IF one$="X10 Diagnostics"
  179.       GOSUB diagnostic
  180.     ELSE IF one$="Set X10 Clock"
  181.       GOSUB set_x10_clock
  182.     ELSE IF one$="Direct Commands"
  183.       GOSUB direct_commands
  184.     ENDIF
  185.     CLOSEW 2
  186.     evt&=0
  187.     ~MENU_TNORMAL(menu_adr%,tit&,1)
  188.   ENDIF
  189. LOOP
  190. PROCEDURE quit
  191.   IF updat|=1
  192.     m$="You are ending without saving|file for units or steps,|is that OK?"
  193.     ALERT 3,m$,2,"Yes|No",z|
  194.     IF z|=2
  195.       GOTO qretrn
  196.     ENDIF
  197.   ENDIF
  198.   GOSUB comend
  199. qretrn:
  200. RETURN
  201. PROCEDURE blurb
  202.   CLEARW 2
  203.   PRINT AT(5,2);"DARKROOM by Howard MacOdrum  Copyright 1990 by Antic Publishing"
  204.   PRINT AT(10,3);"This program makes use of the RESOURCE FILE generator"
  205.   PRINT AT(5,4);"supplied with GFA BASIC version 3."
  206.   PRINT AT(10,6);"The program reserves memory to load the created RESOURCE File and"
  207.   PRINT AT(5,7);"and when the ""QUIT"" option of the FILE portion of the main menu is"
  208.   PRINT AT(5,8);"used the memory is released. Therfore you should always end the"
  209.   PRINT AT(5,9);"program in that fashion otherwise repeated usage will cause"
  210.   PRINT AT(5,10);"you to run out of memory."
  211.   PRINT AT(5,12);" Object numbers of the trees were obtained by using the ""RESOURCE ANALYZER"""
  212.   PRINT AT(5,13);"program contained in ""Programming with GFA BASIC 3.0"" by"
  213.   PRINT AT(5,14);"Gottfried P. Engels & Markus C. Gorgens and published by MICHTRON"
  214.   PRINT AT(5,16);"If any changes are made to the Resource file using the RESOURCE FILE"
  215.   PRINT AT(5,17);"generator new object numbers must be obtained and care must be"
  216.   PRINT AT(5,18);"exercised that groupings of object #s is maintained. See individual"
  217.   PRINT AT(5,19);"subroutines for usage of object no groupings."
  218.   PRINT AT(15,21);" Press any key for the remainder of message."
  219.   REPEAT
  220.   UNTIL INKEY$<>""
  221.   CLEARW 2
  222.   PRINT AT(4,2);"The program creates/maintains a file that may be used in different"
  223.   PRINT AT(2,3);"modes."
  224.   PRINT AT(30,5);"NORMAL MODE"
  225.   PRINT AT(4,6);"The file is stored in memory of the X10 POWERHOUSE module. The"
  226.   PRINT AT(2,7);"X10 clock then controls when the steps will be acted on. When this"
  227.   PRINT AT(2,8);"is being used seconds portion of the file are ignored since the"
  228.   PRINT AT(2,9);"X10 only accepts hours and minutes."
  229.   PRINT AT(30,11);"DIRECT MODE (Run from file)"
  230.   PRINT AT(4,12);"ST clock is used to control the action of the steps. When this "
  231.   PRINT AT(2,13);"mode,is used days of week and security class are ignored.This mode"
  232.   PRINT AT(2,14);"is independent from any file that may be stored in X10 memory. Direct"
  233.   PRINT AT(2,15);"commands are given and the ST must be on line during the whole cycle."
  234.   PRINT AT(4,16);"Hours/mins/seconds are relative to when ""Run from file"" action is"
  235.   PRINT AT(2,17);"is taken and have no relation to clock setting of ST."
  236.   PRINT AT(15,19);"Press any key to return to main menu."
  237.   REPEAT
  238.   UNTIL INKEY$<>""
  239. RETURN
  240. PROCEDURE store_step_file
  241.   itm|=1
  242.   DO
  243.     EXIT IF stpfil$(0,itm|)="***"
  244.     INC itm|
  245.   LOOP
  246.   IF updat|=0
  247.     ALERT 1,"File not changed or|created.",1,"RETURN",z|
  248.     GOTO store_return
  249.   ENDIF
  250. retry_store:
  251.   FILESELECT "\*.DRK","",stp_file$
  252.   IF stp_file$="" OR RIGHT$(stp_file$,1)="\"
  253.     ALERT 1,"No File name is|being specified.",1,"RETRY|RETURN",z|
  254.     IF z|=1
  255.       GOTO retry_store
  256.     ELSE
  257.       GOTO store_return
  258.     ENDIF
  259.   ELSE
  260.     z|=INSTR(stp_file$,".")
  261.     IF z|=0
  262.       stp_file$=stp_file$+".DRK"
  263.     ELSE
  264.       stp_file$=MID$(stp_file$,1,z|)+"DRK"
  265.     ENDIF
  266.     OPEN "O",#1,stp_file$
  267.     STORE #1,unit_desc$(),272
  268.     STORE #1,stpfil$(),itm|*(noflds|+1)
  269.     CLOSE #1
  270.     updat|=0
  271.   ENDIF
  272. store_return:
  273. RETURN
  274. PROCEDURE load_step_file
  275.   stp_file$=""
  276.   FILESELECT "\*.DRK","",stp_file$
  277.   IF stp_file$="" OR RIGHT$(stp_file$,1)="\"
  278.     ALERT 1,"No DRK file| is being loaded!",1,"Cancel",z|
  279.   ELSE IF NOT EXIST(stp_file$)
  280.     ALERT 3,"DRK File not found!",1,"Cancel",z|
  281.   ELSE
  282.     OPEN "I",#1,stp_file$
  283.     RECALL #1,unit_desc$(),272,nut%
  284.     RECALL #1,stpfil$(),maxitems|*(noflds|+1),nitm%
  285.     CLOSE #1
  286.     FOR cy|=nitm%/(noflds|+1) TO maxitems|
  287.       stpfil$(0,cy|)="***"
  288.     NEXT cy|
  289.   ENDIF
  290. RETURN
  291. PROCEDURE stp_scroll_det
  292.   IF stpfil$(0,1)="***"
  293.     ALERT 3,"No File loaded|start new|or return",1,"RETURN|NEW",z|
  294.     IF z|=2
  295.       stpitm|=1
  296.       GOSUB stp_up_det
  297.     ELSE
  298.       GOTO scrl_ret
  299.     ENDIF
  300.   ENDIF
  301.   dx%=1
  302. re_scroll:
  303.   CLEARW 2
  304.   GOSUB insert_detail
  305.   GOSUB gem_draw(stp_scrl_adr%)
  306.   IF ex_obj%=>scrl_f_det_line| AND ex_obj%<=scrl_l_det_line|
  307.     stpitm|=dx%+(ex_obj%-scrl_f_det_line|)
  308.     IF stpfil$(0,stpitm|)="***"
  309.     dec_detail:
  310.       DEC stpitm|
  311.       IF stpfil$(0,stpitm|)<>"***"
  312.         INC stpitm|
  313.         GOTO act_on_detail
  314.       ELSE
  315.         GOTO dec_detail
  316.       ENDIF
  317.     ENDIF
  318.   act_on_detail:
  319.     GOSUB stp_up_det
  320.     GOTO re_scroll
  321.   ENDIF
  322.   IF ex_obj%=scrl_up|
  323.     dx%=dx%-16
  324.     IF dx%<1
  325.       dx%=1
  326.     ENDIF
  327.     GOSUB insert_detail
  328.     GOTO re_scroll
  329.   ENDIF
  330.   IF ex_obj%=scrl_down|
  331.     dx%=dx%+16
  332.     IF dx%>maxitems| OR stpfil$(0,dx%-1)="***"
  333.       dx%=dx%-16
  334.     ENDIF
  335.     GOSUB insert_detail
  336.     GOTO re_scroll
  337.   ENDIF
  338.   IF ex_obj%=scrl_sort|
  339.     itm|=1
  340.     DO                                  ! find length of file for sort
  341.       EXIT IF stpfil$(0,itm|)="***"                        ! end of file
  342.       INC itm|
  343.     LOOP
  344.     DEC itm|
  345.     FOR cx|=1 TO itm|-1
  346.       FOR cy|=1 TO itm|-cx|
  347.         IF stpfil$(0,cy|)>stpfil$(0,cy|+1)
  348.           FOR cz|=0 TO 6
  349.             SWAP stpfil$(cz|,cy|),stpfil$(cz|,cy|+1)
  350.           NEXT cz|
  351.         ENDIF
  352.       NEXT cy|
  353.     NEXT cx|
  354.     GOTO re_scroll
  355.   ENDIF
  356.   IF ex_obj%=scrl_return|
  357.     cx|=1
  358.     sav_tim$=stpfil$(0,cx|)
  359.     DO
  360.       EXIT IF stpfil$(0,cx|)="***"
  361.       IF stpfil$(0,cx|)<sav_tim$
  362.         seq_mesg$="Error detected:|step     has earlier time|than step    "
  363.         MID$(seq_mesg$,23,3)=STR$(cx|)
  364.         MID$(seq_mesg$,53,3)=STR$(cx|-1)
  365.         ALERT 3,seq_mesg$,1,"RETURN",z|
  366.         GOTO re_scroll
  367.       ENDIF
  368.       sav_tim$=stpfil$(0,cx|)
  369.       INC cx|
  370.     LOOP
  371.     GOTO scrl_ret
  372.   ENDIF
  373. scrl_ret:
  374. RETURN
  375. PROCEDURE insert_detail
  376.   lin|=0
  377.   FOR cx|=dx% TO dx%+15
  378.     wkdlin$=SPACE$(68)
  379.     IF stpfil$(0,cx|)<>"***"
  380.       IF cx|<10
  381.         MID$(wkdlin$,1,3)="  "+STR$(cx|)
  382.       ELSE IF cx|<100
  383.         MID$(wkdlin$,1,3)=" "+STR$(cx|)
  384.       ELSE
  385.         MID$(wkdlin$,1,3)=STR$(cx|)
  386.       ENDIF
  387.       MID$(wkdlin$,5,8)=MID$(stpfil$(0,cx|),1,2)+":"+MID$(stpfil$(0,cx|),3,2)+":"+MID$(stpfil$(0,cx|),5,2)
  388.       IF stpfil$(1,cx|)="0"
  389.         MID$(wkdlin$,14,4)="OFF "
  390.       ELSE IF stpfil$(1,cx|)="1"
  391.         MID$(wkdlin$,14,4)="ON  "
  392.       ELSE
  393.         MID$(wkdlin$,14,4)="D-"+stpfil$(1,cx|)
  394.       ENDIF
  395.       MID$(wkdlin$,19,2)=stpfil$(2,cx|)+","
  396.       MID$(wkdlin$,21,22)=stpfil$(3,cx|)
  397.       MID$(wkdlin$,39,1)=stpfil$(4,cx|)
  398.       MID$(wkdlin$,41,7)=stpfil$(5,cx|)
  399.       MID$(wkdlin$,49,20)=stpfil$(6,cx|)
  400.     ENDIF
  401.     CHAR{{OB_SPEC(stp_scrl_adr%,scrl_f_det_line|+lin|)}}=wkdlin$
  402.     INC lin|
  403.   NEXT cx|
  404. RETURN
  405. PROCEDURE stp_up_det
  406.   updat|=1
  407. after_alt:
  408.   hit_unit|=0
  409.   CLEARW 2
  410.   '
  411.   ' set all buttons  off
  412.   '
  413.   OB_STATE(stp_updt_adr%,up_off_func|)=BCLR(OB_STATE(stp_updt_adr%,up_off_func|),0)
  414.   FOR cx|=0 TO 1
  415.     OB_STATE(stp_updt_adr%,up_old|+cx|)=BCLR(OB_STATE(stp_updt_adr%,up_old|+cx|),0)
  416.     OB_STATE(stp_updt_adr%,up_norm|+cx|)=BCLR(OB_STATE(stp_updt_adr%,up_norm|+cx|),0)
  417.   NEXT cx|
  418.   FOR cx|=0 TO 6
  419.     OB_STATE(stp_updt_adr%,up_sun_day|+cx|)=BCLR(OB_STATE(stp_updt_adr%,up_sun_day|+cx|),0)
  420.   NEXT cx|
  421.   FOR cx|=0 TO 15
  422.     OB_STATE(stp_updt_adr%,up_on_func|+cx|)=BCLR(OB_STATE(stp_updt_adr%,up_on_func|+cx|),0)
  423.     OB_STATE(stp_updt_adr%,up_f_house|+cx|)=BCLR(OB_STATE(stp_updt_adr%,up_f_house|+cx|),0)
  424.     OB_STATE(stp_updt_adr%,up_f_unit|+cx|)=BCLR(OB_STATE(stp_updt_adr%,up_f_unit|+cx|),0)
  425.   NEXT cx|
  426.   '
  427.   '
  428.   IF stpfil$(0,stpitm|)="***"
  429.     stpfil$(0,stpitm|)="000000"     ! time
  430.     stpfil$(1,stpitm|)="1"        ! function on
  431.     stpfil$(2,stpitm|)="A"        ! house equals A
  432.     stpfil$(3,stpitm|)="1---------------"       ! unit equals 1
  433.     stpfil$(4,stpitm|)="N"        ! security equals Normal
  434.     stpfil$(5,stpitm|)="S------"  ! day equals sunday
  435.     stpfil$(6,stpitm|)="____________________"    ! Description
  436.     OB_STATE(stp_updt_adr%,up_new|)=BSET(OB_STATE(stp_updt_adr%,up_new|),0)
  437.   ELSE
  438.     OB_STATE(stp_updt_adr%,up_old|)=BSET(OB_STATE(stp_updt_adr%,up_old|),0)
  439.   ENDIF
  440.   wrk_step$=STR$(stpitm|)
  441.   IF LEN(wrk_step$)=1
  442.     wrk_step$="  "+wrk_step$
  443.   ELSE IF LEN(wrk_step$)=2
  444.     wrk_step$=" "+wrk_step$
  445.   ENDIF
  446.   CHAR{{OB_SPEC(stp_updt_adr%,up_step|)}}=wrk_step$
  447.   CHAR{{OB_SPEC(stp_updt_adr%,up_time|)}}=stpfil$(0,stpitm|)
  448.   CHAR{{OB_SPEC(stp_updt_adr%,up_desc|)}}=stpfil$(6,stpitm|)
  449.   IF stpfil$(4,stpitm|)="N"
  450.     OB_STATE(stp_updt_adr%,up_norm|)=BSET(OB_STATE(stp_updt_adr%,up_norm|),0)
  451.   ELSE
  452.     OB_STATE(stp_updt_adr%,up_secr|)=BSET(OB_STATE(stp_updt_adr%,up_secr|),0)
  453.   ENDIF
  454.   FOR cx|=0 TO 6
  455.     IF MID$(stpfil$(5,stpitm|),cx|+1,1)<>"-"
  456.       OB_STATE(stp_updt_adr%,up_sun_day|+cx|)=BSET(OB_STATE(stp_updt_adr%,up_sun_day|+cx|),0)
  457.     ENDIF
  458.   NEXT cx|
  459.   cx|=VAL(stpfil$(1,stpitm|))
  460.   OB_STATE(stp_updt_adr%,up_off_func|+cx|)=BSET(OB_STATE(stp_updt_adr%,up_off_func|+cx|),0)
  461.   cx|=ASC(stpfil$(2,stpitm|))-ASC("A")
  462.   OB_STATE(stp_updt_adr%,up_f_house|+cx|)=BSET(OB_STATE(stp_updt_adr%,up_f_house|+cx|),0)
  463.   FOR cx|=0 TO 15
  464.     IF MID$(stpfil$(3,stpitm|),cx|+1,1)<>"-"
  465.       OB_STATE(stp_updt_adr%,up_f_unit|+cx|)=BSET(OB_STATE(stp_updt_adr%,up_f_unit|+cx|),0)
  466.     ENDIF
  467.   NEXT cx|
  468.   GOSUB gem_draw(stp_updt_adr%)
  469.   '
  470.   ' Store current selected data in file area
  471.   '
  472.   stpfil$(0,stpitm|)=CHAR{{OB_SPEC(stp_updt_adr%,up_time|)}}
  473.   IF MID$(stpfil$(0,stpitm|),1,2)>"23" OR MID$(stpfil$(0,stpitm|),3,2)>"59" OR MID$(stpfil$(0,stpitm|),5,2)>"59"
  474.     error1$="Hrs SB 0-23 min-sec 0-59"
  475.   ELSE
  476.     error1$=""
  477.   ENDIF
  478.   IF CHAR{{OB_SPEC(stp_updt_adr%,up_desc|)}}<>"____________________"
  479.     stpfil$(6,stpitm|)=CHAR{{OB_SPEC(stp_updt_adr%,up_desc|)}}
  480.   ELSE
  481.     stpfil$(6,stpitm|)=""
  482.   ENDIF
  483.   IF BTST(OB_STATE(stp_updt_adr%,up_secr|),0)
  484.     stpfil$(4,stpitm|)="Y"
  485.   ELSE
  486.     stpfil$(4,stpitm|)="N"
  487.   ENDIF
  488.   stpfil$(5,stpitm|)=""
  489.   hit_day|=0
  490.   FOR cx|=0 TO 6
  491.     IF BTST(OB_STATE(stp_updt_adr%,up_sun_day|+cx|),0)
  492.       hit_day|=1
  493.       stpfil$(5,stpitm|)=stpfil$(5,stpitm|)+LEFT$(daystr$(cx|))
  494.     ELSE
  495.       stpfil$(5,stpitm|)=stpfil$(5,stpitm|)+"-"
  496.     ENDIF
  497.   NEXT cx|
  498.   stpfil$(3,stpitm|)=""
  499.   hit_unit|=0
  500.   FOR cx|=0 TO 15
  501.     IF BTST(OB_STATE(stp_updt_adr%,up_on_func|+cx|),0)
  502.       stpfil$(1,stpitm|)=STR$(cx|+1)
  503.     ENDIF
  504.     IF BTST(OB_STATE(stp_updt_adr%,up_f_house|+cx|),0)
  505.       stpfil$(2,stpitm|)=CHR$(ASC("A")+cx|)
  506.     ENDIF
  507.     IF BTST(OB_STATE(stp_updt_adr%,up_f_unit|+cx|),0)
  508.       hit_unit|=1
  509.       stpfil$(3,stpitm|)=stpfil$(3,stpitm|)+RIGHT$(STR$(cx|+1))
  510.     ELSE
  511.       stpfil$(3,stpitm|)=stpfil$(3,stpitm|)+"-"
  512.     ENDIF
  513.   NEXT cx|
  514.   IF BTST(OB_STATE(stp_updt_adr%,up_off_func|),0)
  515.     stpfil$(1,stpitm|)="0"
  516.   ENDIF
  517.   '
  518.   IF LEN(error1$)>0 OR hit_unit|<>1 OR hit_day|<>1
  519.     ermsg$="Error(s) in input:"
  520.     IF LEN(error1$)>0
  521.       ermsg$=ermsg$+"|"+error1$
  522.     ENDIF
  523.     IF hit_unit|<>1
  524.       ermsg$=ermsg$+"|"+"Some unit must be selected"
  525.     ENDIF
  526.     IF hit_day|<>1
  527.       ermsg$=ermsg$+"|"+"No day was selected"
  528.     ENDIF
  529.     ALERT 3,ermsg$,1,"RETURN",z|
  530.     GOTO after_alt
  531.   ENDIF
  532.   '
  533.   IF ex_obj%=up_insert|
  534.     FOR cx|=maxitems| TO stpitm|+1 STEP -1
  535.       FOR cy|=0 TO 6
  536.         SWAP stpfil$(cy|,cx|-1),stpfil$(cy|,cx|)
  537.       NEXT cy|
  538.     NEXT cx|
  539.     GOTO after_alt
  540.   ENDIF
  541.   '
  542.   IF ex_obj%=up_delete|
  543.     FOR cx|=stpitm| TO maxitems|
  544.       EXIT IF stpfil$(0,cx|)="***"
  545.       FOR cy|=0 TO 6
  546.         stpfil$(cy|,cx|)=stpfil$(cy|,cx|+1)
  547.       NEXT cy|
  548.     NEXT cx|
  549.   ENDIF
  550.   '
  551.   IF ex_obj%=up_d_units|
  552.     GOSUB update_unit_desc
  553.     GOTO after_alt
  554.   ENDIF
  555.   '
  556.   IF ex_obj%=up_adjust|
  557.     adjitm|=stpitm|
  558.     first_tim$=stpfil$(0,adjitm|)
  559.     FOR cx|=adjitm| TO maxitems|
  560.       EXIT IF stpfil$(0,cx|)="***"
  561.       last_tim$=stpfil$(0,cx|)
  562.     NEXT cx|
  563.   redo_adjust:
  564.     CLEARW 2
  565.     CHAR{{OB_SPEC(adj_tim_adr%,adj_value|)}}="000000"
  566.     OB_STATE(adj_tim_adr%,adj_plus|)=BSET(OB_STATE(adj_tim_adr%,adj_plus|),0)
  567.     OB_STATE(adj_tim_adr%,adj_minus|)=BCLR(OB_STATE(adj_tim_adr%,adj_minus|),0)
  568.     GOSUB gem_draw(adj_tim_adr%)
  569.     '
  570.     '  Back from display
  571.     '
  572.     adj_str_tim$=CHAR{{OB_SPEC(adj_tim_adr%,adj_value|)}}
  573.     IF MID$(adj_str_tim$,1,2)>"23" OR MID$(adj_str_tim$,3,2)>"59" OR MID$(adj_str_tim$,5,2)>"59"
  574.       ALERT 3,"Input error:|Hrs SB 0-23,min-sec SB 0-59",1,"RETURN",z|
  575.       GOTO redo_adjust
  576.     ENDIF
  577.     IF BTST(OB_STATE(adj_tim_adr%,adj_plus|),0)
  578.       IF VAL(adj_str_tim$)+VAL(last_tim$)>240000
  579.         ALERT 3,"Input error,adjust time|would make last item|greater than 2400 hrs",1,"RETURN",z|
  580.         GOTO redo_adjust
  581.       ENDIF
  582.     ELSE
  583.       IF VAL(first_tim$)-VAL(adj_str_tim$)<0
  584.         ALERT 3,"Input error,adjust time|would make time minus|value",1,"RETURN",z|
  585.         GOTO redo_adjust
  586.       ENDIF
  587.     ENDIF
  588.     adj_tot_sec%=VAL(MID$(adj_str_tim$,1,2))*3600
  589.     ADD adj_tot_sec%,VAL(MID$(adj_str_tim$,3,2))*60
  590.     ADD adj_tot_sec%,VAL(MID$(adj_str_tim$,5,2))
  591.     FOR cx|=adjitm| TO maxitems|
  592.       EXIT IF stpfil$(0,cx|)="***"
  593.       wk_tot_sec%=(VAL(MID$(stpfil$(0,cx|),1,2)))*3600
  594.       ADD wk_tot_sec%,(VAL(MID$(stpfil$(0,cx|),3,2)))*60
  595.       ADD wk_tot_sec%,VAL(MID$(stpfil$(0,cx|),5,2))
  596.       IF BTST(OB_STATE(adj_tim_adr%,adj_plus|),0)
  597.         ADD wk_tot_sec%,adj_tot_sec%
  598.       ELSE
  599.         SUB wk_tot_sec%,adj_tot_sec%
  600.       ENDIF
  601.       GOSUB sec_to_clock
  602.       stpfil$(0,cx|)=clock_work$
  603.     NEXT cx|
  604.     GOTO after_alt
  605.   ENDIF
  606. RETURN
  607. PROCEDURE sec_to_clock
  608.   adj_hrs|=TRUNC(wk_tot_sec%/3600)
  609.   adj_mins|=TRUNC((MOD(wk_tot_sec%,3600))/60)
  610.   adj_secs|=MOD(MOD(wk_tot_sec%,3600),60)
  611.   clock_work$=""
  612.   IF adj_hrs|>9
  613.     clock_work$=STR$(adj_hrs|)
  614.   ELSE
  615.     clock_work$="0"+STR$(adj_hrs|)
  616.   ENDIF
  617.   IF adj_mins|>9
  618.     clock_work$=clock_work$+STR$(adj_mins|)
  619.   ELSE
  620.     clock_work$=clock_work$+"0"+STR$(adj_mins|)
  621.   ENDIF
  622.   IF adj_secs|>9
  623.     clock_work$=clock_work$+STR$(adj_secs|)
  624.   ELSE
  625.     clock_work$=clock_work$+"0"+STR$(adj_secs|)
  626.   ENDIF
  627. RETURN
  628. PROCEDURE ready_x10
  629.   ~XBIOS(rsconf|,baud|,flow|,ucr|,rsr%,tsr%,scr%)
  630.   OPEN "U",#8,"aux:"
  631.   ' clear x10 reply buffer area it accumulates until a request empties it
  632. frstx10:
  633.   IF INP?(1)
  634.     z|=INP(1)
  635.     GOTO frstx10
  636.   ENDIF
  637. RETURN
  638. PROCEDURE run_x10
  639.   IF stpfil$(0,1)="***"
  640.     ALERT 3,"No file created|or loaded, nothing|to run.",1,"RETURN",z|
  641.     GOTO rreturn
  642.   ENDIF
  643.   GOSUB ready_x10
  644.   GOSUB asktime           ! Ask time only to be sure x10 online
  645.   GOSUB x10ack          ! sb FFFFFF1
  646.   ARRAYFILL hsuntab%(),0
  647.   no_steps|=1
  648.   DO
  649.     EXIT IF stpfil$(0,no_steps|)="***"             ! end of table
  650.     INC no_steps|
  651.   LOOP
  652.   DEC no_steps|
  653.   fin_sec%=VAL(MID$(stpfil$(0,no_steps|),5,2))+60*VAL(MID$(stpfil$(0,no_steps|),3,2))+3600*VAL(MID$(stpfil$(0,no_steps|),1,2))
  654.   start_sec%=TIMER/200
  655.   CLEARW 2
  656.   DEFTEXT 1,0,0,6
  657.   TEXT 16,15*ry|,"Step     Function          Description"
  658.   TEXT 250,65*ry|,"Time remaining"
  659.   TEXT 100,90*ry|,"Step"
  660.   TEXT 300,90*ry|,"Process"
  661.   TEXT 200,115*ry|,"House and Unit(s)"
  662.   TEXT 200,160*ry|," To abort enter a or A"
  663.   DEFTEXT 1,0,0,32
  664.   FOR cx|=1 TO no_steps|
  665.     step_sec%=VAL(MID$(stpfil$(0,cx|),5,2))+60*VAL(MID$(stpfil$(0,cx|),3,2))+3600*VAL(MID$(stpfil$(0,cx|),1,2))
  666.     '
  667.     REPEAT
  668.       z$=INKEY$
  669.       IF UPPER$(z$)="A"
  670.         DEFTEXT 1,0,0,13
  671.         CLOSE #8
  672.         GOSUB comend
  673.       ENDIF
  674.       curr_time%=TIMER/200-start_sec%
  675.       IF cx|=1
  676.         TEXT 96,45*ry|,"Waiting for first step!"
  677.       ENDIF
  678.       wk_tot_sec%=step_sec%-curr_time%
  679.       IF wk_tot_sec%<0
  680.         print_time$="PENDING "
  681.       ELSE
  682.         GOSUB sec_to_clock
  683.         print_time$=MID$(clock_work$,1,2)+":"+MID$(clock_work$,3,2)+":"+MID$(clock_work$,5,2)
  684.       ENDIF
  685.       TEXT 140,95*ry|,print_time$
  686.       wk_tot_sec%=fin_sec%-curr_time%
  687.       IF wk_tot_sec%<0
  688.         print_time$="FINISHED"
  689.       ELSE
  690.         GOSUB sec_to_clock
  691.       ENDIF
  692.       print_time$=MID$(clock_work$,1,2)+":"+MID$(clock_work$,3,2)+":"+MID$(clock_work$,5,2)
  693.       '      TEXT 380,95*ry|,wk_tim_min$+":"+wk_tim_sec$
  694.       TEXT 380,95*ry|,print_time$
  695.     UNTIL curr_time%>step_sec%
  696.     '
  697.     '
  698.     TEXT 16,45*ry|,STR$(cx|)
  699.     TEXT 96,45*ry|,SPACE$(40)     ! blank out funtion & desc
  700.     TEXT 8,145*ry|,SPACE$(40)      ! blank out house & units
  701.     TEXT 232,45*ry|,stpfil$(6,cx|)
  702.     IF stpfil$(1,cx|)="0"
  703.       wkfunc$="Off"
  704.     ELSE IF stpfil$(1,cx|)="1"
  705.       wkfunc$="On"
  706.     ELSE
  707.       wkfunc$="D "+stpfil$(1,cx|)
  708.     ENDIF
  709.     TEXT 96,45*ry|,wkfunc$
  710.     TEXT 150,145*ry|,stpfil$(2,cx|)+","+stpfil$(3,cx|)
  711.     '
  712.     ' ready and execute direct commands
  713.     '
  714.     x10cmnd|(17)=1                                          ! direct comand
  715.     x10cmnd|(18)=funct|(VAL(stpfil$(1,cx|)))                ! off ,on or dim
  716.     x10cmnd|(19)=househex|((1+ASC(stpfil$(2,cx|))-ASC("A"))) ! housecode
  717.     '
  718.     '  get and insert unit codes
  719.     '
  720.     x10cmnd|(20)=0                       ! set units 9 to 16 to zero
  721.     x10cmnd|(21)=0                       !     "     1 to 8  "
  722.     '
  723.     FOR cy|=1 TO 16
  724.       IF MID$(stpfil$(3,cx|),cy|,1)<>"-"
  725.         IF cy|>8
  726.           x10cmnd|(20)=BSET(x10cmnd|(20),16-cy|)
  727.         ELSE
  728.           x10cmnd|(21)=BSET(x10cmnd|(21),8-cy|)
  729.         ENDIF
  730.         '
  731.         ' fill house and unit table 0=off, 1=on or 2-16 on dim
  732.         hsuntab|(1+(ASC(stpfil$(2,cx|))-ASC("A")),cy|)=VAL(stpfil$(1,cx|))
  733.       ENDIF
  734.     NEXT cy|
  735.     '
  736.     '      establish check sum
  737.     '
  738.     chksum%=0
  739.     FOR cy|=18 TO 21
  740.       chksum%=chksum%+x10cmnd|(cy|)
  741.     NEXT cy|
  742.     x10cmnd|(22)=MOD(chksum%,256)
  743.     '
  744.     x10cmlen|=22
  745.     GOSUB x10cmnd
  746.     x10lim|=7
  747.     GOSUB x10reply
  748.     GOSUB x10ack                  !sb FFFFFF1
  749.     x10lim|=12
  750.     GOSUB x10reply
  751.     GOSUB x10ack                  !SB FFFFFF1 etc:
  752.     GOSUB x10dirverify             ! verify x10 sends same as received
  753.   NEXT cx|
  754.   DEFTEXT 1,0,0,13
  755. rreturn:
  756.   CLOSE #8
  757. RETURN
  758. PROCEDURE x10cmnd
  759.   FOR xx|=1 TO x10cmlen|
  760.     OUT #8,x10cmnd|(xx|)
  761.   NEXT xx|
  762. RETURN
  763. PROCEDURE x10reply
  764.   startim%=TIMER
  765.   xx|=1
  766.   DO
  767.     IF (TIMER-startim%)/200>10
  768.       ALERT 3,"X10 module did not respond|within 10 seconds|no recovery.",1,"END|END",z|
  769.       END
  770.     ENDIF
  771.     EXIT IF xx|>x10lim|
  772.     IF INP?(1)
  773.       x10reply|(xx|)=INP(1)
  774.       INC xx|
  775.     ENDIF
  776.   LOOP
  777. RETURN
  778. PROCEDURE x10ack
  779.   FOR xy|=1 TO 6          ! sb FFFFFF1
  780.     IF x10reply|(xy|)<>255
  781.       x10reply|(7)=0
  782.     ENDIF
  783.   NEXT xy|
  784.   IF x10reply|(7)<>1
  785.     ALERT 3,"X10 not responding|check connections|or power on ",1,"END",z|
  786.     GOSUB final
  787.   ENDIF
  788. RETURN
  789. PROCEDURE x10dirverify
  790.   chksum%=0                      ! is check sum correct ?
  791.   FOR xx|=8 TO 11
  792.     chksum%=chksum%+x10reply|(xx|)
  793.   NEXT xx|
  794.   IF MOD(chksum%,256)<>x10reply|(12)
  795.   x10error:
  796.     ALERT 3,"X10 not giving same|commands received.|NO RECOVERY",1,"END|END",z|
  797.     GOSUB final
  798.   ENDIF
  799.   REM are  unit codes correct
  800.   IF x10cmnd|(20)<>x10reply|(9) OR x10cmnd|(21)<>x10reply|(10)
  801.     GOTO x10error
  802.   ENDIF
  803.   REM see x10 manual for oddball on-off-base code conglomeration
  804.   x10unit%=x10reply|(8) MOD 16
  805.   x10base%=x10reply|(8)-x10unit%
  806.   IF x10base%<0
  807.     x10base%=0
  808.   ENDIF
  809.   IF x10base%<>x10cmnd|(19)    !is base code same
  810.     GOTO x10error
  811.   ENDIF
  812.   IF x10unit%<4        !x10 replies on&off codes same, returns 4 for all dim codes
  813.     IF x10unit%<>x10cmnd|(18)
  814.       GOTO x10error
  815.     ENDIF
  816.   ENDIF
  817. RETURN
  818. PROCEDURE asktime
  819.   x10cmnd|(17)=4
  820.   x10cmlen|=17
  821.   GOSUB x10cmnd
  822.   x10lim|=12
  823.   GOSUB x10reply
  824.   GOSUB x10ack
  825.   svmi|=x10reply|(8)
  826.   chksum%=x10reply|(8)
  827.   svhr|=x10reply|(9)
  828.   ADD chksum%,svhr|
  829.   svday|=x10reply|(10)
  830.   ADD chksum%,svday|
  831.   svbase|=x10reply|(11)
  832.   ADD chksum%,svbase|
  833.   IF MOD(chksum%,256)<>x10reply|(12)
  834.     ALERT 3,"X10 not returning|correct check sum",1,"END",z|
  835.     GOSUB final
  836.   ENDIF
  837. RETURN
  838. PROCEDURE base_code
  839.   ALERT 3,"WARNING if base code|is changed all events|in X10 are erased,",1,"OKAY|RETURN",z|
  840.   IF z|=2
  841.     GOTO base_return
  842.   ENDIF
  843.   GOSUB ready_x10
  844.   GOSUB asktime
  845.   CLEARW 2
  846.   FOR cx|=1 TO 16
  847.     IF x10reply|(11)=househex|(cx|)
  848.       OB_STATE(x10_base_adr%,x10_base_a|+(cx|-1))=BSET(OB_STATE(x10_base_adr%,x10_base_a|+(cx|-1)),0)
  849.     ENDIF
  850.   NEXT cx|
  851.   GOSUB gem_draw(x10_base_adr%)
  852.   x10cmnd|(17)=0
  853.   FOR cx|=1 TO 16
  854.     IF BTST(OB_STATE(x10_base_adr%,x10_base_a|+(cx|-1)),0)
  855.       change_base|=househex|(cx|)
  856.     ENDIF
  857.   NEXT cx|
  858.   IF x10reply|(11)=change_base|
  859.     GOTO close_base
  860.   ENDIF
  861.   x10cmnd|(18)=change_base|
  862.   x10cmlen|=18
  863.   GOSUB x10cmnd
  864.   x10lim|=7
  865.   GOSUB x10reply
  866.   GOSUB x10ack
  867. close_base:
  868.   CLOSE #8
  869. base_return:
  870. RETURN
  871. PROCEDURE diagnostic
  872.   CLEARW 2
  873.   ALERT 3,"Diagnostic procedure|will erase stored|file in X10",1,"OKAY|RETURN",z|
  874.   IF z|=2
  875.     GOTO diag_return
  876.   ENDIF
  877.   BOX 223,148,404,258
  878.   BOX 225,150,402,256
  879.   PRINT AT(32,12);"Please wait while"
  880.   PRINT AT(32,13);"X10 command module"
  881.   PRINT AT(32,14);"is tested."
  882.   GOSUB ready_x10
  883.   GOSUB asktime
  884.   x10cmnd|(17)=7
  885.   x10cmlen|=17
  886.   GOSUB x10cmnd
  887.   PAUSE 50
  888.   x10lim|=7
  889.   GOSUB x10reply
  890.   CLEARW 2
  891.   IF x10reply|(7)=0
  892.     ALERT 1,"X10 Passed analysis.",1,"RETURN",z|
  893.     GOSUB sendclock       ! Restore time to reset status bit after diag set to 0
  894.     x10lim|=7
  895.     GOSUB x10reply
  896.     GOSUB sendclock       ! must be done twice status still zero after 1st time
  897.     x10lim|=7
  898.     GOSUB x10reply
  899.     GOSUB x10ack
  900.   ELSE
  901.     ALERT 3,"X10 Failed analysis",1,"RETURN",z|
  902.   ENDIF
  903.   CLOSE #8
  904. diag_return:
  905. RETURN
  906. PROCEDURE sendclock
  907.   x10cmnd|(17)=2
  908.   x10cmnd|(18)=svmi|
  909.   x10cmnd|(19)=svhr|
  910.   x10cmnd|(20)=svday|
  911.   x10cmnd|(21)=svmi|+svhr|+svday|
  912.   x10cmlen|=21
  913.   GOSUB x10cmnd
  914. RETURN
  915. PROCEDURE print_steps
  916.   IF stpfil$(0,1)="***"
  917.     CLEARW 2
  918.     ALERT 3,"No steps loaded or created.|Nothing available to print",1,"RETURN|END",z|
  919.     IF z|=2
  920.       GOSUB comend
  921.     ELSE
  922.       GOTO pretn
  923.     ENDIF
  924.   ENDIF
  925.   GOSUB ready_printer
  926.   IF print_ok|=0
  927.     GOTO pretn
  928.   ENDIF
  929.   PRINT AT(2,4);"Enter file description."
  930.   LINE INPUT a$
  931.   PRINT #2,a$
  932.   PRINT #2
  933.   PRINT #2,"Step";"  Description";TAB(26);"Time";TAB(35);"Func";TAB(40);"House & Units";TAB(60);"Sec";TAB(64);"Day"
  934.   step|=1
  935.   DO
  936.     EXIT IF stpfil$(0,step|)="***"
  937.     PRINT #2,TAB(1);step|;TAB(5);stpfil$(6,step|);TAB(26);MID$(stpfil$(0,step|),1,2);":";MID$(stpfil$(0,step|),3,2);":";MID$(stpfil$(0,step|),5,2);
  938.     IF stpfil$(1,step|)="1"
  939.       wk_func$="On"
  940.     ELSE IF stpfil$(1,step|)="0"
  941.       wk_func$="Off"
  942.     ELSE
  943.       wk_func$="D "+stpfil$(1,step|)
  944.     ENDIF
  945.     PRINT #2,TAB(35);wk_func$;TAB(40);stpfil$(2,step|);",";stpfil$(3,step|);TAB(61);stpfil$(4,step|);TAB(64);stpfil$(5,step|)
  946.     INC step|
  947.   LOOP
  948.   CLOSE #2
  949. pretn:
  950. RETURN
  951. PROCEDURE file_analysis
  952.   IF stpfil$(0,1)="***"
  953.     ALERT 3,"No steps created or|loaded. Nothing |to analyze,",1,"RETURN",z|
  954.     GOTO anreturn
  955.   ENDIF
  956.   ARRAYFILL hsuntab|(),0
  957.   step|=1
  958.   errstep|=1
  959.   DO
  960.     EXIT IF stpfil$(0,step|)="***"
  961.     ansfil$(errstep|,5)=""
  962.     housno|=1+ASC(stpfil$(2,step|))-ASC("A")
  963.     FOR cy|=1 TO 16
  964.       IF MID$(stpfil$(3,step|),cy|,1)<>"-"
  965.         IF stpfil$(1,step|)="0"             ! function is off
  966.           IF hsuntab|(housno|,cy|)>0        ! unit was on normal situation
  967.             hsuntab|(housno|,cy|)=0         ! set table off
  968.             GOTO noerror
  969.           ELSE
  970.             ansfil$(errstep|,2)="1"
  971.             ansfil$(errstep|,3)="0"
  972.             GOTO rester
  973.           ENDIF
  974.         ELSE                             ! function is on
  975.           IF hsuntab|(housno|,cy|)=0        ! table contained off normal
  976.             hsuntab|(housno|,cy|)=step|     ! save in table step turned on
  977.             GOTO noerror
  978.           ELSE
  979.             ansfil$(errstep|,2)="2"
  980.             ansfil$(errstep|,3)=STR$(hsuntab|(housno|,cy|))
  981.           rester:
  982.             ansfil$(errstep|,1)=STR$(step|)
  983.             ansfil$(errstep|,4)=stpfil$(2,step|)
  984.             ansfil$(errstep|,5)=ansfil$(errstep|,5)+STR$(cy|)+"-"
  985.           ENDIF
  986.         ENDIF
  987.       noerror:
  988.       ENDIF
  989.     NEXT cy|
  990.     IF LEN(ansfil$(errstep|,5))>1
  991.       INC errstep|
  992.     ENDIF
  993.     INC step|
  994.     EXIT IF errstep|>49
  995.   LOOP
  996.   '
  997.   FOR cx|=1 TO 16
  998.     FOR cy|=1 TO 16
  999.       IF hsuntab|(cx|,cy|)<>0
  1000.         ansfil$(errstep|,1)=STR$(hsuntab|(cx|,cy|))
  1001.         ansfil$(errstep|,3)="0"
  1002.         ansfil$(errstep|,2)="3"
  1003.         ansfil$(errstep|,5)=STR$(cy|)
  1004.         ansfil$(errstep|,4)=CHR$(64+cx|)
  1005.         INC errstep|
  1006.       ENDIF
  1007.       EXIT IF errstep|>50
  1008.     NEXT cy|
  1009.     EXIT IF errstep|>50
  1010.   NEXT cx|
  1011.   IF errstep|>50
  1012.     ALERT 3,"More than 50 errors|analysis stopped",1,"CONTINUE",z|
  1013.     GOTO prntscrn
  1014.   ENDIF
  1015.   IF errstep|=1
  1016.     ALERT 1,"Good job !|no errors found.",1,"RETURN",z|
  1017.     GOTO anreturn
  1018.   ENDIF
  1019. prntscrn:
  1020.   anlmsg2$=STR$(errstep|-1)+anlmsg1$
  1021.   ALERT 3,anlmsg2$,1,"PAPER|VIDEO",z|
  1022.   IF z|=1
  1023.     GOTO rdyprnt
  1024.   ELSE
  1025.     cy|=1
  1026.   dismorer:
  1027.     PRINT AT(2,1);"   Step  Err  Prev  House Unit(s)"
  1028.     PRINT AT(2,2);"        code  step"
  1029.     PRINT AT(2,18);anlmsg3$
  1030.     PRINT AT(2,19);anlmsg4$
  1031.     PRINT AT(2,20);anlmsg5$
  1032.     PRINT AT(1,3);" "
  1033.     FOR cx|=cy| TO cy|+11
  1034.       IF LEN(ansfil$(cx|,1))>1
  1035.         fpp|=5
  1036.       ELSE
  1037.         fpp|=6
  1038.       ENDIF
  1039.       IF LEN(ansfil$(cx|,3))>1
  1040.         spp|=16
  1041.       ELSE
  1042.         spp|=17
  1043.       ENDIF
  1044.       PRINT TAB(fpp|);ansfil$(cx|,1);TAB(12);ansfil$(cx|,2);TAB(spp|);ansfil$(cx|,3);TAB(23);ansfil$(cx|,4);TAB(29);ansfil$(cx|,5)
  1045.     NEXT cx|
  1046.     IF errstep|-cx|>0
  1047.       PRINT AT(2,16);"There are still ";errstep|-cx|;"  error(s) remaining, after review press any key."
  1048.       REPEAT
  1049.       UNTIL INKEY$<>""
  1050.       CLEARW 2
  1051.       cy|=cx|
  1052.       GOTO dismorer
  1053.     ELSE
  1054.       PRINT AT(2,16);"Last of errors displayed, after review press any key,"
  1055.       REPEAT
  1056.       UNTIL INKEY$<>""
  1057.       GOTO anreturn
  1058.     ENDIF
  1059.   ENDIF
  1060. rdyprnt:
  1061.   GOSUB ready_printer
  1062.   IF print_ok|=0
  1063.     GOTO anreturn
  1064.   ENDIF
  1065.   PRINT #2,"     Step  Err  Prev  House Unit(s)"
  1066.   PRINT #2,"          code  step"
  1067.   PRINT #2
  1068.   FOR cx|=1 TO errstep|-1
  1069.     IF LEN(ansfil$(cx|,1))>1
  1070.       fpp|=5
  1071.     ELSE
  1072.       fpp|=6
  1073.     ENDIF
  1074.     IF LEN(ansfil$(cx|,3))>1
  1075.       spp|=16
  1076.     ELSE
  1077.       spp|=17
  1078.     ENDIF
  1079.     PRINT #2,TAB(fpp|);ansfil$(cx|,1);TAB(12);ansfil$(cx|,2);TAB(spp|);ansfil$(cx|,3);TAB(23);ansfil$(cx|,4);TAB(29);ansfil$(cx|,5)
  1080.   NEXT cx|
  1081.   PRINT #2
  1082.   PRINT #2,anlmsg3$
  1083.   PRINT #2,anlmsg4$
  1084.   PRINT #2,anlmsg5$
  1085.   CLOSE #2
  1086. anreturn:
  1087.   ARRAYFILL hsuntab|(),0
  1088. RETURN
  1089. PROCEDURE file_to_x10
  1090.   IF stpfil$(0,1)="***"
  1091.     ALERT 3,"No steps created|   or loaded.|  Fahampt?",1,"YES|END",z|
  1092.     IF z|=2
  1093.       GOSUB comend
  1094.     ELSE
  1095.       GOTO rreturn
  1096.     ENDIF
  1097.   ENDIF
  1098.   GOSUB ready_x10
  1099.   CLEARW 2
  1100.   GOSUB asktime
  1101.   '
  1102.   ' down load of base code erases all events in x10
  1103.   '
  1104.   x10cmlen|=18
  1105.   x10cmnd|(17)=0
  1106.   x10cmnd|(18)=svbase|
  1107.   GOSUB x10cmnd
  1108.   GOSUB sendclock       ! Restore time to reset status bit after down load set to 0
  1109.   x10lim|=7
  1110.   GOSUB x10reply
  1111.   GOSUB sendclock       ! must be done twice status still zero after 1st time
  1112.   x10lim|=7
  1113.   GOSUB x10reply
  1114.   GOSUB x10ack
  1115.   '
  1116.   '
  1117.   x10cmnd|(17)=3                        ! download events
  1118.   FOR cx|=1 TO maxitems|
  1119.     PRINT AT(15,10);"Storing File to X10 Controller, Step No, ";cx|
  1120.     IF stpfil$(0,cx|)="***"
  1121.       GOTO bumpstor
  1122.     ENDIF
  1123.     x10cmnd|(18)=SHL|(cx|-1,3)             ! step no
  1124.     x10cmnd|(19)=SHR|(cx|-1,5)             ! step no
  1125.     x10cmnd|(20)=0
  1126.     x10cmlen|=20
  1127.     IF stpfil$(4,cx|)="Y"
  1128.       x10cmnd|(20)=9                     ! security mode
  1129.     ELSE
  1130.       x10cmnd|(20)=8                     ! normal mode
  1131.     ENDIF
  1132.     x10cmnd|(21)=0
  1133.     FOR cy|=1 TO 7
  1134.       IF MID$(stpfil$(5,cx|),cy|,1)<>"-"
  1135.         x10cmnd|(21)=x10cmnd|(21)+dayhex|(cy|-1)
  1136.       ENDIF
  1137.     NEXT cy|
  1138.     x10cmnd|(22)=VAL(MID$(stpfil$(0,cx|),1,2))
  1139.     x10cmnd|(23)=VAL(MID$(stpfil$(0,cx|),3,2))
  1140.     x10cmnd|(24)=0
  1141.     x10cmnd|(25)=0
  1142.     FOR cy|=1 TO 16
  1143.       IF MID$(stpfil$(3,cx|),cy|,1)<>"-"
  1144.         IF cy|>8
  1145.           x10cmnd|(25)=BSET(x10cmnd|(25),16-cy|)
  1146.         ELSE
  1147.           x10cmnd|(24)=BSET(x10cmnd|(24),8-cy|)
  1148.         ENDIF
  1149.       ENDIF
  1150.     NEXT cy|
  1151.     x10cmnd|(26)=househex|((1+ASC(stpfil$(2,cx|))-ASC("A")))
  1152.     x10cmnd|(27)=funct|(VAL(stpfil$(1,cx|)))
  1153.     '
  1154.     '  get check sum
  1155.     '
  1156.     chksum%=0
  1157.     FOR cy|=20 TO 27
  1158.       chksum%=chksum%+x10cmnd|(cy|)
  1159.     NEXT cy|
  1160.     x10cmnd|(28)=MOD(chksum#,256)
  1161.     x10cmlen|=28
  1162.     GOSUB x10cmnd
  1163.     PAUSE 50
  1164.   bumpstor:
  1165.   NEXT cx|
  1166.   CLOSE #8
  1167. RETURN
  1168. PROCEDURE set_x10_clock
  1169.   GOSUB ready_x10
  1170.   GOSUB asktime
  1171.   '
  1172.   ' Set all buttons off
  1173.   '
  1174.   FOR cx|=0 TO 6
  1175.     OB_STATE(x10_clock_adr%,x10_clk_sun|+cx|)=BCLR(OB_STATE(x10_clock_adr%,x10_clk_sun|+cx|),0)
  1176.   NEXT cx|
  1177.   '
  1178.   wk_time$=STR$(svhr|)
  1179.   IF LEN(wk_time$)=1
  1180.     wk_time$="0"+wk_time$
  1181.   ENDIF
  1182.   wk_min$=STR$(svmi|)
  1183.   IF LEN(wk_min$)=1
  1184.     wk_min$="0"+wk_min$
  1185.   ENDIF
  1186.   wk_time$=wk_time$+wk_min$
  1187.   CHAR{{OB_SPEC(x10_clock_adr%,x10_clk_tim|)}}=wk_time$
  1188.   FOR cx|=0 TO 6
  1189.     IF svday|=dayhex|(cx|)
  1190.       OB_STATE(x10_clock_adr%,x10_clk_sun|+cx|)=BSET(OB_STATE(x10_clock_adr%,x10_clk_sun|+cx|),0)
  1191.     ENDIF
  1192.   NEXT cx|
  1193.   CLEARW 2
  1194. redraw_anal:
  1195.   GOSUB gem_draw(x10_clock_adr%)
  1196.   temp_time$=CHAR{{OB_SPEC(x10_clock_adr%,x10_clk_tim|)}}
  1197.   IF MID$(temp_time$,1,2)>"23" OR MID$(temp_time$,3,2)>"59"
  1198.     ALERT 3,"24 hour clock|highest allowable is:|23:59",0,"OK",z|
  1199.     GOTO redraw_anal
  1200.   ENDIF
  1201.   IF temp_time$<>wk_time$
  1202.     clock_up|=1
  1203.     svhr|=VAL(MID$(temp_time$,1,2))
  1204.     svmi|=VAL(MID$(temp_time$,3,2))
  1205.   ENDIF
  1206.   FOR cx|=0 TO 6
  1207.     IF BTST(OB_STATE(x10_clock_adr%,x10_clk_sun|+cx|),0)
  1208.       temp_hex|=dayhex|(cx|)
  1209.       IF temp_hex|<>svday|
  1210.         clock_up|=1
  1211.         svday|=temp_hex|
  1212.       ENDIF
  1213.     ENDIF
  1214.   NEXT cx|
  1215.   IF clock_up|=1
  1216.     clock_up|=0
  1217.     GOSUB sendclock
  1218.     x10lim|=7
  1219.     GOSUB x10reply
  1220.     GOSUB x10ack
  1221.   ENDIF
  1222.   CLOSE #8
  1223. RETURN
  1224. PROCEDURE direct_commands
  1225.   GOSUB ready_x10
  1226.   '
  1227.   ' set all buttons  off
  1228.   '
  1229.   OB_STATE(x10_direct_adr%,x10_dir_func_off|)=BCLR(OB_STATE(x10_direct_adr%,x10_dir_func_off|),0)
  1230.   FOR cx|=0 TO 15
  1231.     OB_STATE(x10_direct_adr%,x10_dir_hous_a|+cx|)=BCLR(OB_STATE(x10_direct_adr%,x10_dir_hous_a|+cx|),0)
  1232.     OB_STATE(x10_direct_adr%,x10_dir_unit_1|+cx|)=BCLR(OB_STATE(x10_direct_adr%,x10_dir_unit_1|+cx|),0)
  1233.     OB_STATE(x10_direct_adr%,x10_dir_func_on|+cx|)=BCLR(OB_STATE(x10_direct_adr%,x10_dir_func_on|+cx|),0)
  1234.   NEXT cx|
  1235.   '
  1236.   ' set default
  1237.   OB_STATE(x10_direct_adr%,x10_dir_hous_a|)=BSET(OB_STATE(x10_direct_adr%,x10_dir_hous_a|),0)
  1238.   OB_STATE(x10_direct_adr%,x10_dir_unit_1|)=BSET(OB_STATE(x10_direct_adr%,x10_dir_unit_1|),0)
  1239.   OB_STATE(x10_direct_adr%,x10_dir_func_on|)=BSET(OB_STATE(x10_direct_adr%,x10_dir_func_on|),0)
  1240.   '
  1241. display_direct:
  1242.   CLEARW 2
  1243.   GOSUB gem_draw(x10_direct_adr%)
  1244.   '
  1245.   '
  1246.   IF ex_obj%=x10_dir_display_unit|
  1247.     GOSUB update_unit_desc
  1248.     GOTO display_direct
  1249.   ENDIF
  1250.   '
  1251.   '
  1252.   IF ex_obj%=x10_dir_execute|
  1253.     '
  1254.     ' ready and execute direct commands
  1255.     '
  1256.     FOR cx|=18 TO 22
  1257.       x10cmnd|(cx|)=0
  1258.     NEXT cx|
  1259.     x10cmnd|(17)=1                                          ! direct comand
  1260.     FOR cx|=0 TO 16
  1261.       IF BTST(OB_STATE(x10_direct_adr%,x10_dir_func_on|+cx|-1),0)
  1262.         x10cmnd|(18)=funct|(cx|)
  1263.       ENDIF
  1264.     NEXT cx|
  1265.     FOR cx|=1 TO 16
  1266.       IF BTST(OB_STATE(x10_direct_adr%,x10_dir_hous_a|+cx|-1),0)
  1267.         x10cmnd|(19)=househex|(cx|)             ! housecode
  1268.       ENDIF
  1269.     NEXT cx|
  1270.     '
  1271.     '  get and insert unit codes
  1272.     '
  1273.     FOR cx|=1 TO 8
  1274.       IF BTST(OB_STATE(x10_direct_adr%,x10_dir_unit_1|+cx|-1),0)
  1275.         x10cmnd|(21)=BSET(x10cmnd|(21),8-cx|)
  1276.       ENDIF
  1277.       IF BTST(OB_STATE(x10_direct_adr%,x10_dir_unit_9|+cx|-1),0)
  1278.         x10cmnd|(20)=BSET(x10cmnd|(20),8-cx|)
  1279.       ENDIF
  1280.     NEXT cx|
  1281.     '
  1282.     IF x10cmnd|(20)=0 AND x10cmnd|(21)=0
  1283.       ALERT 3,"Some unit must|be selected",1,"RETRY",z|
  1284.       GOTO display_direct
  1285.     ELSE
  1286.       '
  1287.       '      establish check sum
  1288.       '
  1289.       chksum%=0
  1290.       FOR cx|=18 TO 21
  1291.         chksum%=chksum%+x10cmnd|(cx|)
  1292.       NEXT cx|
  1293.       x10cmnd|(22)=MOD(chksum%,256)
  1294.       '
  1295.       x10cmlen|=22
  1296.       GOSUB x10cmnd
  1297.       x10lim|=7
  1298.       GOSUB x10reply
  1299.       GOSUB x10ack                  !sb FFFFFF1
  1300.       x10lim|=12
  1301.       GOSUB x10reply
  1302.       GOSUB x10ack                  !SB FFFFFF1 etc:
  1303.       GOSUB x10dirverify             ! verify x10 sends same as received
  1304.       GOTO display_direct
  1305.     ENDIF
  1306.   ENDIF
  1307.   CLOSE #8
  1308. RETURN
  1309. PROCEDURE x10_print
  1310.   GOSUB ready_printer
  1311.   IF print_ok|=0
  1312.     GOTO no_prnt_x10
  1313.   ENDIF
  1314.   GOSUB ready_x10
  1315.   GOSUB asktime
  1316.   x10cmnd|(17)=5
  1317.   x10cmlen|=17
  1318.   GOSUB x10cmnd
  1319.   PAUSE 250
  1320.   GOSUB long_reply
  1321.   CLEARW 2
  1322.   PRINT AT(2,4);"Enter file description."
  1323.   LINE INPUT a$
  1324.   PRINT #2,a$
  1325.   PRINT #2
  1326.   FOR cx|=0 TO 6
  1327.     IF svday|=dayhex|(cx|)
  1328.       fdday$=daystr$(cx|)
  1329.     ENDIF
  1330.   NEXT cx|
  1331.   FOR cx|=1 TO 16
  1332.     IF svbase|=househex|(cx|)
  1333.       fdbase$=CHR$(ASC("A")+(cx|-1))
  1334.     ENDIF
  1335.   NEXT cx|
  1336.   PRINT #2,"X10 Memory - File contents";"     Time ";svhr|;":";svmi|;"     Day ";fdday$;"     Base Code ";fdbase$
  1337.   PRINT #2
  1338.   PRINT #2,"Step";"  Time";TAB(12);"Func";TAB(18);"House & Units";TAB(39);"Sec";TAB(44);"Day"
  1339.   PRINT
  1340.   PRINT
  1341.   chksum%=0
  1342.   pstep|=1
  1343.   FOR cx%=8 TO xx%-2
  1344.     IF x10reply|(cx%)=255
  1345.       GOTO bumpw
  1346.     ENDIF
  1347.     FOR cy|=0 TO 7
  1348.       upfld$(cy|)=""
  1349.     NEXT cy|
  1350.     '
  1351.     ' get mode
  1352.     ADD chksum%,x10reply|(cx%)
  1353.     IF x10reply|(cx%)=8
  1354.       upfld$(0)="N"
  1355.     ELSE IF x10reply|(cx%)=9
  1356.       upfld$(0)="Y"
  1357.     ENDIF
  1358.     IF x10reply|(cx%+1)>127
  1359.       GOTO x10pfilhrs
  1360.     ENDIF
  1361.     '
  1362.     ' get days
  1363.     '
  1364.     ADD chksum%,x10reply|(cx%+1)
  1365.     upfld$(1)="-------"
  1366.     FOR cy|=0 TO 5
  1367.       IF BTST(x10reply|(cx%+1),cy|)
  1368.         MID$(upfld$(1),cy|+2,1)=LEFT$(daystr$(cy|+1))
  1369.       ENDIF
  1370.     NEXT cy|
  1371.     IF BTST(x10reply|(cx%+1),6)
  1372.       MID$(upfld$(1),1,1)=LEFT$(daystr$(0))
  1373.     ENDIF
  1374.     '
  1375.   x10pfilhrs:
  1376.     '
  1377.     ' decode time hrs
  1378.     '
  1379.     ADD chksum%,x10reply|(cx%+2)
  1380.     IF x10reply|(cx%+2)>23
  1381.       GOTO x10pfilmins
  1382.     ENDIF
  1383.     upfld$(2)=STR$(x10reply|(cx%+2))
  1384.     IF LEN(upfld$(2))<2
  1385.       upfld$(2)="0"+upfld$(2)
  1386.     ENDIF
  1387.   x10pfilmins:
  1388.     '
  1389.     ' decode time mins
  1390.     '
  1391.     ADD chksum%,x10reply|(cx%+3)
  1392.     IF x10reply|(cx%+3)>59
  1393.       GOTO x10pfilun1
  1394.     ENDIF
  1395.     upfld$(3)=STR$(x10reply|(cx%+3))
  1396.     IF LEN(upfld$(3))<2
  1397.       upfld$(3)="0"+upfld$(3)
  1398.     ENDIF
  1399.   x10pfilun1:
  1400.     '
  1401.     ' decode units 1 - 8
  1402.     '
  1403.     ADD chksum%,x10reply|(cx%+4)
  1404.     FOR cy|=0 TO 7
  1405.       IF BTST(x10reply|(cx%+4),cy|)
  1406.         upfld$(4)=STR$(8-cy|)+upfld$(4)
  1407.       ELSE
  1408.         upfld$(4)="-"+upfld$(4)
  1409.       ENDIF
  1410.     NEXT cy|
  1411.     '
  1412.     ' decode units 9 - 16
  1413.     '
  1414.     ADD chksum%,x10reply|(cx%+5)
  1415.     FOR cy|=0 TO 7
  1416.       IF BTST(x10reply|(cx%+5),cy|)
  1417.         wkupfld$=STR$(16-cy|)
  1418.         wkupfld$=RIGHT$(wkupfld$,1)
  1419.         upfld$(5)=wkupfld$+upfld$(5)
  1420.       ELSE
  1421.         upfld$(5)="-"+upfld$(5)
  1422.       ENDIF
  1423.     NEXT cy|
  1424.     '
  1425.     ' decode house
  1426.     '
  1427.     ADD chksum%,x10reply|(cx%+6)
  1428.     FOR cy|=1 TO 16
  1429.       IF x10reply|(cx%+6)=househex|(cy|)
  1430.         upfld$(6)=CHR$(ASC("A")+(cy|-1))
  1431.       ENDIF
  1432.     NEXT cy|
  1433.     '
  1434.     ' decode function
  1435.     '
  1436.     ADD chksum%,x10reply|(cx%+7)
  1437.     IF x10reply|(cx%+7)=2
  1438.       upfld$(7)="ON"
  1439.     ELSE IF x10reply|(cx%+7)=3
  1440.       upfld$(7)="OFF"
  1441.     ENDIF
  1442.     FOR cy|=2 TO 16
  1443.       IF x10reply|(cx%+7)=funct|(cy|)
  1444.         upfld$(7)="D-"+STR$(cy|)
  1445.       ENDIF
  1446.     NEXT cy|
  1447.     ADD cx%,7
  1448.     FOR cy|=0 TO 7
  1449.       IF upfld$(cy|)=""
  1450.         x10fderr|=1
  1451.       ENDIF
  1452.     NEXT cy|
  1453.     IF x10fderr|=0
  1454.       PRINT #2;pstep|;TAB(5);upfld$(2);TAB(8);upfld$(3);TAB(12);upfld$(7);TAB(18);upfld$(6);",";upfld$(4);upfld$(5);TAB(40);upfld$(0);TAB(44);upfld$(1)
  1455.     ENDIF
  1456.   bumpw:
  1457.     ADD pstep|,1
  1458.   NEXT cx%
  1459.   PRINT
  1460.   IF x10fderr|=1
  1461.     ALERT 3,"Meaningless Data|maybe X10 Analysis|was just done.",1,"RETURN",z|
  1462.     x10fderr|=0
  1463.     GOTO prx10freturn
  1464.   ENDIF
  1465.   IF x10reply|(xx%-1)<>MOD(chksum%,256)
  1466.     ALERT 3,"X10 Data does not|add up to check|sum.",1,"RETURN|END",z|
  1467.     IF z|=2
  1468.       CLOSE #2
  1469.       CLOSE #8
  1470.       GOSUB final
  1471.     ENDIF
  1472.   ENDIF
  1473. prx10freturn:
  1474.   CLOSE #2
  1475.   CLOSE #8
  1476. no_prnt_x10:
  1477. RETURN
  1478. PROCEDURE long_reply
  1479.   xx%=1
  1480. strt_x10lrg:
  1481.   IF INP?(1)
  1482.     x10reply|(xx%)=INP(1)
  1483.     INC xx%
  1484.     GOTO strt_x10lrg
  1485.   ENDIF
  1486. RETURN
  1487. PROCEDURE ready_printer
  1488.   OPEN "O",#2,"LST:"
  1489. retry_print:
  1490.   IF GEMDOS(17)
  1491.     print_ok|=1
  1492.   ELSE
  1493.     print_ok|=0
  1494.     ALERT 3,"Printer not|responding!",1,"RETRY|RETURN",z|
  1495.     IF z|=1
  1496.       GOTO retry_print
  1497.     ELSE
  1498.       CLOSE #2
  1499.     ENDIF
  1500.   ENDIF
  1501. RETURN
  1502. PROCEDURE update_unit_desc
  1503.   CLEARW 2
  1504.   house_pointer%=0
  1505. reform_house_unit:
  1506.   CHAR{{OB_SPEC(unit_desc_adr%,ud_house|)}}=CHR$(ASC("A")+house_pointer%)
  1507.   CHAR{{OB_SPEC(unit_desc_adr%,ud_house_desc|)}}=unit_desc$(0,house_pointer%)
  1508.   FOR cx%=0 TO 15
  1509.     CHAR{{OB_SPEC(unit_desc_adr%,ud_unit_desc1|+cx%)}}=unit_desc$(cx%+1,house_pointer%)
  1510.   NEXT cx%
  1511.   GOSUB gem_draw(unit_desc_adr%)
  1512.   IF CHAR{{OB_SPEC(unit_desc_adr%,ud_house_desc|)}}="_________________________"
  1513.     unit_desc$(0,house_pointer%)=""
  1514.   ELSE
  1515.     updat|=1
  1516.     unit_desc$(0,house_pointer%)=CHAR{{OB_SPEC(unit_desc_adr%,ud_house_desc|)}}
  1517.   ENDIF
  1518.   FOR cx%=0 TO 15
  1519.     IF CHAR{{OB_SPEC(unit_desc_adr%,ud_unit_desc1|+cx%)}}="__________________________"
  1520.       unit_desc$(cx%+1,house_pointer%)=""
  1521.     ELSE
  1522.       updat|=1
  1523.       unit_desc$(cx%+1,house_pointer%)=CHAR{{OB_SPEC(unit_desc_adr%,ud_unit_desc1|+cx%)}}
  1524.     ENDIF
  1525.   NEXT cx%
  1526.   IF ex_obj%=ud_house_up|
  1527.     INC house_pointer%
  1528.     IF house_pointer%>15
  1529.       house_pointer%=15
  1530.     ENDIF
  1531.     GOTO reform_house_unit
  1532.   ENDIF
  1533.   IF ex_obj%=ud_house_prev|
  1534.     DEC house_pointer%
  1535.     IF house_pointer%<0
  1536.       house_pointer%=0
  1537.     ENDIF
  1538.     GOTO reform_house_unit
  1539.   ENDIF
  1540.   '
  1541. RETURN
  1542. PROCEDURE print_units
  1543.   GOSUB ready_printer
  1544.   IF print_ok|=1
  1545.     FOR cx|=0 TO 15
  1546.       FOR cy|=1 TO 16
  1547.         IF unit_desc$(cy|,cx|)<>""
  1548.           IF tab_amt|=0
  1549.             PRINT #2
  1550.             PRINT #2;TAB(25);"House ";CHR$(ASC("A")+cx|);'unit_desc$(0,cx|)
  1551.             PRINT #2
  1552.             tab_amt|=1
  1553.           ENDIF
  1554.           IF tab_amt|>40
  1555.             tab_amt|=1
  1556.             PRINT #2
  1557.           ENDIF
  1558.           PRINT #2;TAB(tab_amt|);"Unit # ";cy|;'unit_desc$(cy|,cx|);
  1559.           ADD tab_amt|,39
  1560.         ENDIF
  1561.       NEXT cy|
  1562.       IF tab_amt|>0
  1563.         PRINT #2
  1564.         tab_amt|=0
  1565.       ENDIF
  1566.     NEXT cx|
  1567.     CLOSE #2
  1568.   ENDIF
  1569. RETURN
  1570. PROCEDURE comend
  1571.   FOR cx|=1 TO 16
  1572.     FOR cy|=1 TO 16
  1573.       IF hsuntab|(cx|,cy|)<>0
  1574.         onunsw|=1
  1575.         onunit$(cx|)=onunit$(cx|)+STR$(cy|)+"-"
  1576.       ENDIF
  1577.     NEXT cy|
  1578.   NEXT cx|
  1579.   IF onunsw|=1
  1580.     GOSUB ready_x10
  1581.     CLEARW 2
  1582.     ALERT 3,"Program has left some|units in on status|END will turn all off",1,"END|REVIEW",z|
  1583.     IF z|=2
  1584.       CLEARW 2
  1585.       PRINT AT(5,2);" Below are the units that were left on by program. After review, "
  1586.       PRINT AT(5,3);"press any key to turn them all off."
  1587.       cy|=1
  1588.       FOR cx|=1 TO 16
  1589.         IF LEN(onunit$(cx|))>0
  1590.           PRINT AT(10,cy|+5);"HOUSE";'CHR$(64+cx|);'"UNIT(S)";'onunit$(cx|)
  1591.           INC cy|
  1592.         ENDIF
  1593.       NEXT cx|
  1594.       REPEAT
  1595.         z$=INKEY$
  1596.       UNTIL z$<>""
  1597.     ENDIF
  1598.     FOR cx|=1 TO 16
  1599.       IF LEN(onunit$(cx|))>0
  1600.         x10cmnd|(17)=1
  1601.         x10cmnd|(18)=3
  1602.         x10cmnd|(19)=househex|(cx|)
  1603.         x10cmnd|(20)=0
  1604.         x10cmnd|(21)=0
  1605.         FOR cy|=1 TO 16
  1606.           IF hsuntab|(cx|,cy|)<>0
  1607.             IF cy|>8
  1608.               x10cmnd|(20)=BSET(x10cmnd|(20),16-cy|)
  1609.             ELSE
  1610.               x10cmnd|(21)=BSET(x10cmnd|(21),8-cy|)
  1611.             ENDIF
  1612.           ENDIF
  1613.         NEXT cy|
  1614.         chksum%=0
  1615.         FOR cy|=18 TO 21
  1616.           chksum%=chksum%+x10cmnd|(cy|)
  1617.         NEXT cy|
  1618.         x10cmnd|(22)=MOD(chksum%,256)
  1619.         x10cmlen|=22
  1620.         GOSUB x10cmnd
  1621.         x10lim|=7
  1622.         GOSUB x10reply
  1623.         GOSUB x10ack
  1624.         x10lim|=12
  1625.         GOSUB x10reply
  1626.         GOSUB x10ack
  1627.         GOSUB x10dirverify
  1628.       ENDIF
  1629.     NEXT cx|
  1630.     CLOSE #8
  1631.   ENDIF
  1632.   GOSUB final
  1633. RETURN
  1634. PROCEDURE gem_draw(VAR tree_addr%)
  1635.   ~FORM_CENTER(tree_addr%,x%,y%,w%,h%)
  1636.   ~OBJC_DRAW(tree_addr%,0,8,x%,y%,w%,h%)
  1637.   ex_obj%=FORM_DO(tree_addr%,0)
  1638.   ~OBJC_CHANGE(tree_addr%,ex_obj%,0,x%,y%,w%,h%,0,0)
  1639. RETURN
  1640. PROCEDURE final
  1641.   ~MENU_BAR(menu_adr%,0)
  1642.   ~RSRC_FREE()
  1643.   RESERVE FRE(0)+16000
  1644.   END
  1645. RETURN
  1646.